libgfasitarautils/gfasitarautils.pro

TEMPLATE = lib
VERSION = 1.0
CONFIG -= qt app_bundle
CONFIG += c++11 shared thread

HEADERS += \
    src/gfasitarautils.h \
    src/suconv.h \
    src/sucycletimer.h

SOURCES += \
    src/suconv.c \
    src/sucycletimer.cpp

####################################################################################

GFA_LIB_PATH = /usr/lib/gfa
GFA_INC_PATH = /usr/include/gfa
QMAKE_RPATHLINKDIR += $$GFA_LIB_PATH
QMAKE_RPATHDIR += $$GFA_LIB_PATH
QMAKE_DEL_DIR = rmdir --ignore-fail-on-non-empty
QMAKE_LN_SHLIB = :

####################################################################################

CONFIG(debug, debug|release) {
    QMAKE_CXXFLAGS -= -Os
    QMAKE_CFLAGS -= -Os
    QMAKE_CXXFLAGS += -D_DEBUG
    QMAKE_CFLAGS += -D_DEBUG
	TARGET = $$join(TARGET,,,d)
}

linux-buildroot-g++ {
    QMAKE_CXXFLAGS += -D_TARGET_BUILD
    QMAKE_CFLAGS += -D_TARGET_BUILD
    QMAKE_CXXFLAGS += -D_SITARA
    QMAKE_CFLAGS += -D_SITARA
}

####################################################################################

target.path = $$GFA_LIB_PATH
INSTALLS += target

####################################################################################

linux-g++ {
	includes.path = $$GFA_INC_PATH
	includes.extra += -$(INSTALL_FILE) $$PWD/src/gfasitarautils.h $(INSTALL_ROOT)$$includes.path
	includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/src/suconv.h $(INSTALL_ROOT)$$includes.path
	includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/src/sucycletimer.h $(INSTALL_ROOT)$$includes.path
	includes.uninstall += -$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/gfasitarautils.h
	includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/suconv.h
	includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/sucycletimer.h
	INSTALLS += includes
}

####################################################################################

linux-buildroot-g++ {
	exists($$[QT_SYSROOT]) {
		library.path = $$[QT_SYSROOT]$$target.path
		library.extra += -$(INSTALL_PROGRAM) $(TARGET) $(INSTALL_ROOT)$$library.path/$(TARGET)
		library.extra += $$escape_expand(\\n\\t)-$(SYMLINK) $(TARGET) $(INSTALL_ROOT)$$library.path/$(TARGET0)
		library.extra += $$escape_expand(\\n\\t)-$(SYMLINK) $(TARGET) $(INSTALL_ROOT)$$library.path/$(TARGET1)
		library.extra += $$escape_expand(\\n\\t)-$(SYMLINK) $(TARGET) $(INSTALL_ROOT)$$library.path/$(TARGET2)
		library.uninstall += -$(DEL_FILE) $(INSTALL_ROOT)$$library.path/$(TARGET)
		library.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$library.path/$(TARGET0)
		library.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$library.path/$(TARGET1)
		library.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$library.path/$(TARGET2)
		INSTALLS += library

		includes.path = $$[QT_SYSROOT]$$GFA_INC_PATH
		includes.extra += -$(INSTALL_FILE) $$PWD/src/gfasitarautils.h $(INSTALL_ROOT)$$includes.path
		includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/src/suconv.h $(INSTALL_ROOT)$$includes.path
		includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/src/sucycletimer.h $(INSTALL_ROOT)$$includes.path
		includes.uninstall += -$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/gfasitarautils.h
		includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/suconv.h
		includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/sucycletimer.h
		INSTALLS += includes

		itoolchain.target = install_toolchain
		itoolchain.depends = install_library install_includes
		QMAKE_EXTRA_TARGETS += itoolchain

		utoolchain.target = uninstall_toolchain
		utoolchain.depends = uninstall_library uninstall_includes
		QMAKE_EXTRA_TARGETS += utoolchain
	}
}

####################################################################################

deploylib.target = deploylib
deploylib.commands = @echo BASENAME="$(QMAKE_TARGET)" > deploytargets
deploylib.commands += $$escape_expand(\\n\\t)@echo TARGET="$(TARGET)" >> deploytargets
deploylib.commands += $$escape_expand(\\n\\t)@echo TARGET0="$(TARGET0)" >> deploytargets
deploylib.commands += $$escape_expand(\\n\\t)@echo TARGET1="$(TARGET1)" >> deploytargets
deploylib.commands += $$escape_expand(\\n\\t)@echo TARGET2="$(TARGET2)" >> deploytargets
deploylib.commands += $$escape_expand(\\n\\t)@echo HEADERS="\\\"gfasitarautils.h suconv.h sucycletimer.h\\\"" >> deploytargets
PRE_TARGETDEPS += deploylib
QMAKE_EXTRA_TARGETS += deploylib