libgfaservices/summarist/summarist.pro

TEMPLATE = lib
CONFIG   += c++11
CONFIG   -= qt
CONFIG   += staticlib

QMAKE_CXXFLAGS_DEBUG += -Wno-unused-parameter -Wno-unused-but-set-variable -Wno-old-style-cast -pthread
QMAKE_CXXFLAGS += -Wno-old-style-cast -Wstrict-aliasing=0 -pthread
# QMAKE_LIBS += -lm -lstdc++ -pthread -lgfaipc -l:libcommon.a -lmysqlclient
# QMAKE_LIBDIR += $$OUT_PWD/../common $$[QT_SYSROOT]/usr/lib/gfa
QMAKE_RPATHDIR += /usr/lib/gfa

QMAKE_CXXFLAGS += -D_DL_SUMMARIST -D_LIBBUILD -Wno-format-overflow
QMAKE_CFLAGS += -D_DL_SUMMARIST -D_LIBBUILD -Wno-format-overflow

_LIB_PATH = $$[QT_SYSROOT]/usr/lib/gfa/svc/
_INC_PATH = $$[QT_SYSROOT]/usr/include/gfa/svc/summarist/

CONFIG(debug, debug|release) {
	QMAKE_CXXFLAGS -= -Os
	QMAKE_CFLAGS -= -Os
    QMAKE_CXXFLAGS += -D_DEBUG
    QMAKE_CFLAGS += -D_DEBUG
	TARGET = summaristd
	QMAKE_CLEAN += libsummaristd.a
}

CONFIG(release, debug|release) {
    QMAKE_CXXFLAGS += -Wno-unused-parameter -Wno-unused-but-set-variable
    QMAKE_CFLAGS += -Wno-unused-parameter -Wno-unused-but-set-variable
	TARGET = summarist
	QMAKE_CLEAN += libsummarist.a
}

linux-buildroot-g++ {
    QMAKE_CXXFLAGS += -D_TARGET_BUILD
    QMAKE_CFLAGS += -D_TARGET_BUILD
    QMAKE_CXXFLAGS += -DSITARA_BUILD
    QMAKE_CFLAGS += -DSITARA_BUILD
}

INCLUDEPATH += ../  ../common $$(GEBGFADEV)

SOURCES += summarist.cpp

HEADERS += summarist.h

includes.path = $$_INC_PATH
includes.extra += -$(INSTALL_FILE) $$PWD/summarist.h $(INSTALL_ROOT)$$includes.path
includes.uninstall += -$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/summarist.h
INSTALLS += includes

library.path = $$_LIB_PATH
library.extra += -$(INSTALL_FILE) $(TARGET) $(INSTALL_ROOT)$$library.path/$(TARGET)
library.uninstall += -$(DEL_FILE) $(INSTALL_ROOT)$$library.path/$(TARGET)
INSTALLS += library