libgfaservices/datalogger/datalogger.pro

TEMPLATE = lib
CONFIG   += c++11
CONFIG   -= qt
CONFIG   += staticlib

QMAKE_CXXFLAGS_DEBUG += -Wno-unused-parameter -Wno-unused-but-set-variable -pthread
QMAKE_CXXFLAGS += -Wstrict-aliasing=0 -pthread
QMAKE_LIBS += -lm -lstdc++ -pthread -lgfaipcd -l:libcommon.a -lmysqlclient
QMAKE_LIBDIR += $$OUT_PWD/../common $$[QT_SYSROOT]/usr/lib/gfa
QMAKE_RPATHDIR += /usr/lib/gfa
INCLUDEPATH += ../  ../common $$(GEBGFADEV)

QMAKE_CXXFLAGS += -D_DATALOGGER -D_LIBBUILD -Wno-format-overflow
QMAKE_CFLAGS += -D_DATALOGGER -D_LIBBUILD -Wno-format-overflow

_LIB_PATH = $$[QT_SYSROOT]/usr/lib/gfa/svc/
_INC_PATH = $$[QT_SYSROOT]/usr/include/gfa/svc/datalogger/

CONFIG(debug, debug|release) {
	QMAKE_CXXFLAGS -= -Os
	QMAKE_CFLAGS -= -Os
    QMAKE_CXXFLAGS += -D_DEBUG
    QMAKE_CFLAGS += -D_DEBUG
	TARGET = dataloggerd
	QMAKE_CLEAN += libdataloggerd.a
}

CONFIG(release, debug|release) {
    QMAKE_CXXFLAGS += -Wno-unused-parameter -Wno-unused-but-set-variable
    QMAKE_CFLAGS += -Wno-unused-parameter -Wno-unused-but-set-variable
	TARGET = datalogger
	QMAKE_CLEAN += libdatalogger.a
}

linux-buildroot-g++ {
    QMAKE_CXXFLAGS += -D_TARGET_BUILD
    QMAKE_CFLAGS += -D_TARGET_BUILD
    QMAKE_CXXFLAGS += -DSITARA_BUILD
    QMAKE_CFLAGS += -DSITARA_BUILD
}

linux-g++ {
    QMAKE_CXXFLAGS += -Wno-deprecated-declarations
    QMAKE_CFLAGS += -Wno-deprecated-declarations
}

SOURCES += logvar.cpp \
    logbitvar.cpp \
    datalogger.cpp \
    dataloggerclock.cpp

HEADERS += \
    logvar.h \
    datalogger.h

includes.path = $$_INC_PATH
includes.extra += -$(INSTALL_FILE) $$PWD/logvar.h $(INSTALL_ROOT)$$includes.path
includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/datalogger.h $(INSTALL_ROOT)$$includes.path
includes.uninstall += -$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/logvar.h
includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/datalogger.h
INSTALLS += includes

library.path = $$_LIB_PATH
library.extra += -$(INSTALL_FILE) $(TARGET) $(INSTALL_ROOT)$$library.path/$(TARGET)
library.uninstall += -$(DEL_FILE) $(INSTALL_ROOT)$$library.path/$(TARGET)
INSTALLS += library