libgfaservices/shmqml/shmqml.pro

TEMPLATE = lib
QT += qml quick
CONFIG   += c++11
# CONFIG   -= qt
CONFIG   += staticlib

QMAKE_CXXFLAGS_DEBUG += -Wno-unused-parameter -Wno-unused-but-set-variable -Wno-old-style-cast -pthread
QMAKE_CXXFLAGS += -Wno-old-style-cast -Wstrict-aliasing=0 -pthread
QMAKE_RPATHDIR += /usr/lib/gfa

QMAKE_CXXFLAGS += -D_DL_SHMQML -D_LIBBUILD -Wno-deprecated-copy
QMAKE_CFLAGS += -D_DL_SHMQML -D_LIBBUILD -Wno-deprecated-copy

DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

_LIB_PATH = $$[QT_SYSROOT]/usr/lib/gfa/svc/
_INC_PATH = $$[QT_SYSROOT]/usr/include/gfa/svc/shmqml/

CONFIG(debug, debug|release) {
	QMAKE_CXXFLAGS -= -Os
	QMAKE_CFLAGS -= -Os
    QMAKE_CXXFLAGS += -D_DEBUG
    QMAKE_CFLAGS += -D_DEBUG
	TARGET = shmqmld
	QMAKE_CLEAN += libshmqmld.a
}

CONFIG(release, debug|release) {
    QMAKE_CXXFLAGS += -Wno-unused-parameter -Wno-unused-but-set-variable
    QMAKE_CFLAGS += -Wno-unused-parameter -Wno-unused-but-set-variable
	TARGET = shmqml
	QMAKE_CLEAN += libshmqml.a
}

linux-buildroot-g++ {
    QMAKE_CXXFLAGS += -D_TARGET_BUILD
    QMAKE_CFLAGS += -D_TARGET_BUILD
    QMAKE_CXXFLAGS += -DSITARA_BUILD
    QMAKE_CFLAGS += -DSITARA_BUILD
}

INCLUDEPATH += ../  ../common $$(GEBGFADEV)

SOURCES += shmbitvar.cpp \
		shmstrvar.cpp \
		shmvar.cpp


HEADERS += shmvar.h \
		shmthread.h

includes.path = $$_INC_PATH
includes.extra += -$(INSTALL_FILE) $$PWD/shmvar.h $(INSTALL_ROOT)$$includes.path
includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/shmthread.h $(INSTALL_ROOT)$$includes.path
includes.uninstall += -$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/shmvar.h
includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/shmthread.h
INSTALLS += includes

library.path = $$_LIB_PATH
library.extra += -$(INSTALL_FILE) $(TARGET) $(INSTALL_ROOT)$$library.path/$(TARGET)
library.uninstall += -$(DEL_FILE) $(INSTALL_ROOT)$$library.path/$(TARGET)
INSTALLS += library