libgfaservices/mqttcl/mqttcl.pro

TEMPLATE = lib
CONFIG   += c++11
CONFIG   -= qt
CONFIG   += staticlib

QMAKE_CXXFLAGS_DEBUG += -Wno-unused-parameter -Wno-unused-but-set-variable -pthread
QMAKE_CXXFLAGS += -Wstrict-aliasing=0 -pthread
QMAKE_LIBS += -lm -lstdc++ -pthread -lgfaipc -ljansson -l:libcommon.a -lmosquittopp -lmosquitto
QMAKE_LIBDIR += $$OUT_PWD/../common $$[QT_SYSROOT]/usr/lib/gfa
QMAKE_RPATHDIR += /usr/lib/gfa

QMAKE_CXXFLAGS += -D_MQTTCL -D_LIBBUILD -Wno-deprecated-declarations
QMAKE_CFLAGS += -D_MQTTCL -D_LIBBUILD -Wno-deprecated-declarations

_LIB_PATH = $$[QT_SYSROOT]/usr/lib/gfa/svc/
_INC_PATH = $$[QT_SYSROOT]/usr/include/gfa/svc/mqttcl/

CONFIG(debug, debug|release) {
	QMAKE_CXXFLAGS -= -Os
	QMAKE_CFLAGS -= -Os
    QMAKE_CXXFLAGS += -D_DEBUG
    QMAKE_CFLAGS += -D_DEBUG
	TARGET = mqttcld
	QMAKE_CLEAN += libmqttcld.a
}

CONFIG(release, debug|release) {
    QMAKE_CXXFLAGS += -Wno-unused-parameter -Wno-unused-but-set-variable
    QMAKE_CFLAGS += -Wno-unused-parameter -Wno-unused-but-set-variable
	TARGET = mqttcl
	QMAKE_CLEAN += libmqttcl.a
}

linux-buildroot-g++ {
    QMAKE_CXXFLAGS += -D_TARGET_BUILD
    QMAKE_CFLAGS += -D_TARGET_BUILD
    QMAKE_CXXFLAGS += -DSITARA_BUILD
    QMAKE_CFLAGS += -DSITARA_BUILD
}

INCLUDEPATH += ../  ../common $$(GEBGFADEV)

SOURCES += \
    mqttclient.cpp \
    mqttmsg.cpp \
    mqttmsgqueue.cpp \
    mqttmsgpool.cpp \
    mqttvartbl.cpp \
    mqttcfg.cpp

HEADERS += mqttclient.h \
    mqttmsg.h \
    mqttvar.h \
    mqttcfg.h \
    mqttjson.h \
    mqttdbg.h

includes.path = $$_INC_PATH
includes.extra += -$(INSTALL_FILE) $$PWD/mqttclient.h $(INSTALL_ROOT)$$includes.path
includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/mqttmsg.h $(INSTALL_ROOT)$$includes.path
includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/mqttvar.h $(INSTALL_ROOT)$$includes.path
includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/mqttcfg.h $(INSTALL_ROOT)$$includes.path
includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/mqttjson.h $(INSTALL_ROOT)$$includes.path
includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/mqttdbg.h $(INSTALL_ROOT)$$includes.path
includes.uninstall += -$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/mqttclient.h
includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/mqttmsg.h
includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/mqttvar.h
includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/mqttcfg.h
includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/mqttjson.h
includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/mqttdbg.h
INSTALLS += includes

library.path = $$_LIB_PATH
library.extra += -$(INSTALL_FILE) $(TARGET) $(INSTALL_ROOT)$$library.path/$(TARGET)
library.uninstall += -$(DEL_FILE) $(INSTALL_ROOT)$$library.path/$(TARGET)
INSTALLS += library