| 123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596 |
- TEMPLATE = lib
- VERSION = 1.2
- QT += qml quick core
- CONFIG -= app_bundle
- CONFIG += c++11 shared thread
- ####################################################################################
- SOURCES += \
- src/helpers.cpp \
- src/qappctrl.cpp \
- src/qappinfo.cpp \
- src/qmysqlinfo.cpp \
- src/qnetworkinfo.cpp \
- src/qsysinfo.cpp
- HEADERS += \
- src/helpers.h \
- src/qappctrl.h
- ####################################################################################
- GFA_LIB_PATH = /usr/lib/gfa
- GFA_INC_PATH = /usr/include/gfa
- QMAKE_RPATHLINKDIR += $$GFA_LIB_PATH
- QMAKE_RPATHDIR += $$GFA_LIB_PATH
- QMAKE_DEL_DIR = rmdir --ignore-fail-on-non-empty
- QMAKE_LN_SHLIB = :
- ####################################################################################
- CONFIG(debug, debug|release) {
- QMAKE_CXXFLAGS -= -Os
- QMAKE_CFLAGS -= -Os
- QMAKE_CXXFLAGS += -D_DEBUG
- QMAKE_CFLAGS += -D_DEBUG
- TARGET = $$join(TARGET,,,d)
- }
- ####################################################################################
- target.path = $$GFA_LIB_PATH
- INSTALLS += target
- ####################################################################################
- linux-g++ {
- includes.path = $$GFA_INC_PATH
- includes.extra += -$(INSTALL_FILE) $$PWD/src/qappctrl.h $(INSTALL_ROOT)$$includes.path
- includes.uninstall += -$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/qappctrl.h
- INSTALLS += includes
- }
- ####################################################################################
- linux-buildroot-g++ {
- exists($$[QT_SYSROOT]) {
- library.path = $$[QT_SYSROOT]$$target.path
- library.extra += -$(INSTALL_PROGRAM) $(TARGET) $(INSTALL_ROOT)$$library.path/$(TARGET)
- library.extra += $$escape_expand(\\n\\t)-$(SYMLINK) $(TARGET) $(INSTALL_ROOT)$$library.path/$(TARGET0)
- library.extra += $$escape_expand(\\n\\t)-$(SYMLINK) $(TARGET) $(INSTALL_ROOT)$$library.path/$(TARGET1)
- library.extra += $$escape_expand(\\n\\t)-$(SYMLINK) $(TARGET) $(INSTALL_ROOT)$$library.path/$(TARGET2)
- library.uninstall += -$(DEL_FILE) $(INSTALL_ROOT)$$library.path/$(TARGET)
- library.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$library.path/$(TARGET0)
- library.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$library.path/$(TARGET1)
- library.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$library.path/$(TARGET2)
- INSTALLS += library
- includes.path = $$[QT_SYSROOT]$$GFA_INC_PATH
- includes.extra += -$(INSTALL_FILE) $$PWD/src/qappctrl.h $(INSTALL_ROOT)$$includes.path
- includes.uninstall += -$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/qappctrl.h
- INSTALLS += includes
- itoolchain.target = install_toolchain
- itoolchain.depends = install_library install_includes
- QMAKE_EXTRA_TARGETS += itoolchain
- utoolchain.target = uninstall_toolchain
- utoolchain.depends = uninstall_library uninstall_includes
- QMAKE_EXTRA_TARGETS += utoolchain
- }
- QMAKE_CXXFLAGS += -D_TARGET_BUILD
- QMAKE_CFLAGS += -D_TARGET_BUILD
- }
- ####################################################################################
- deploylib.target = deploylib
- deploylib.commands = @echo BASENAME="$(QMAKE_TARGET)" > deploytargets
- deploylib.commands += $$escape_expand(\\n\\t)@echo TARGET="$(TARGET)" >> deploytargets
- deploylib.commands += $$escape_expand(\\n\\t)@echo TARGET0="$(TARGET0)" >> deploytargets
- deploylib.commands += $$escape_expand(\\n\\t)@echo TARGET1="$(TARGET1)" >> deploytargets
- deploylib.commands += $$escape_expand(\\n\\t)@echo TARGET2="$(TARGET2)" >> deploytargets
- deploylib.commands += $$escape_expand(\\n\\t)@echo HEADERS="\\\"qappctrl.h\\\"" >> deploytargets
- PRE_TARGETDEPS += deploylib
- QMAKE_EXTRA_TARGETS += deploylib
|
