gfaservices/svc/rest/rest.pro

DEPLOY_BASEDIR = $$fromfile(../../projal.pri, DEPLOY_BASEDIR)
DEPLOY_SUBDIR = $$fromfile(../../projal.pri, DEPLOY_SUBDIR)

TEMPLATE = app
CONFIG += console c++11
CONFIG -= app_bundle
CONFIG -= qt

QMAKE_CXXFLAGS_DEBUG += -Wno-unused-parameter -Wno-unused-but-set-variable
QMAKE_CXXFLAGS += -Wstrict-aliasing=0

QMAKE_CXXFLAGS += -D_REST
QMAKE_CFLAGS += -D_REST
QMAKE_LIBDIR += $$[QT_SYSROOT]/usr/lib/gfa $$[QT_SYSROOT]/usr/lib/gfa/svc
QMAKE_RPATHDIR += /usr/lib/gfa

QMAKE_LIBS += -lm -lstdc++ -lgfaipc -lulfius -ljansson -pthread -lpthread -lorcania -lcurl -lssl -lcrypto

CONFIG(debug, debug|release) {
    QMAKE_CXXFLAGS -= -Os
    QMAKE_CFLAGS -= -Os
    QMAKE_CXXFLAGS += -D_DEBUG
    QMAKE_CFLAGS += -D_DEBUG
	QMAKE_LIBS += -l:librestd.a -l:libcommond.a
}

CONFIG(release, debug|release) {
    QMAKE_CXXFLAGS += -Wno-unused-parameter -Wno-unused-but-set-variable
    QMAKE_CFLAGS += -Wno-unused-parameter -Wno-unused-but-set-variable
	QMAKE_LIBS += -l:librest.a -l:libcommon.a
}

SOURCES += main.cpp

HEADERS += 

linux-buildroot-g++ {
    target.path = $$DEPLOY_BASEDIR/$$DEPLOY_SUBDIR/rest
    INSTALLS += target
}

################################################################
#                                                              #
# Wenn keine statischen Files verwendet werden, können die     #
# folgenden beiden Blöcke auskommentiert oder gelöscht werden. #
#                                                              #
################################################################

linux-g++ {
	DISTFILES = staticcfg staticfiles
	staticcfg.files = staticfiles.json
    staticcfg.path = $$OUT_PWD
    staticfiles.files = html
    staticfiles.path = $$OUT_PWD
    INSTALLS += staticcfg staticfiles
}

linux-buildroot-g++ {
	DISTFILES = staticcfg staticfiles
	staticcfg.files = staticfiles.json
    staticcfg.path = $$DEPLOY_BASEDIR/$$DEPLOY_SUBDIR/rest
    staticfiles.files = html
    staticfiles.path = $$DEPLOY_BASEDIR/$$DEPLOY_SUBDIR/rest
    INSTALLS += staticcfg staticfiles
}