GfASQLPlugin/mysqlqmlplugin.pro

TEMPLATE = lib
TARGET = mysqlqmlplugin
QT += sql qml
CONFIG += qt plugin c++11

##############################################################

TARGET = $$qtLibraryTarget($$TARGET)
uri = gfa.plugins.qml.mysql

##############################################################

QMAKE_LIBDIR += $$[QT_SYSROOT]/usr/lib/gfa
QMAKE_RPATHLINKDIR += /usr/lib/gfa
QMAKE_RPATHDIR += /usr/lib/gfa

##############################################################

CONFIG(debug, debug|release) {
    QMAKE_CXXFLAGS -= -Os
    QMAKE_CFLAGS -= -Os
    QMAKE_CXXFLAGS += -D_DEBUG
    QMAKE_CFLAGS += -D_DEBUG
}

##############################################################

SOURCES += \
    src/plugin.cpp \
    src/sqldatabase.cpp

HEADERS += \
    src/plugin.h \
    src/sqldatabase.h

##############################################################

qmlPath = $$[QT_INSTALL_QML]/$$replace(uri, \\., /)

##############################################################

linux-g++ {
	QMAKE_POST_LINK += @test -d $(INSTALL_ROOT)$$qmlPath || mkdir -p $(INSTALL_ROOT)$$qmlPath
	QMAKE_POST_LINK += $$escape_expand(\\n\\t)$(COPY_FILE) $$OUT_PWD/$(TARGET) $(INSTALL_ROOT)$$qmlPath/
	QMAKE_POST_LINK += $$escape_expand(\\n\\t)$(COPY_FILE) $$_PRO_FILE_PWD_/qmldir $(INSTALL_ROOT)$$qmlPath/
	QMAKE_POST_LINK += $$escape_expand(\\n\\t)qmlplugindump -nonrelocatable $$uri 1.0 > $$qmlPath/plugins.qmltypes
	QMAKE_POST_LINK += $$escape_expand(\\n\\t)$(COPY_FILE) $(INSTALL_ROOT)$$qmlPath/plugins.qmltypes $$_PRO_FILE_PWD_/
}

##############################################################

linux-buildroot-g++ {
	qmlDir.files = $$_PRO_FILE_PWD_/qmldir
	qmlDir.path = $$qmlPath
	target.path = $$qmlPath
	copy_qmltyes.path = $$qmlPath
	copy_qmltyes.files = $$_PRO_FILE_PWD_/plugins.qmltypes
	INSTALLS += target qmlDir copy_qmltyes
	DISTFILES += qmlDir copy_qmltyes
}