ApplicationLauncher/applicationlauncher.pro

TEMPLATE = lib
TARGET = ApplicationLauncher
QT += qml quick
CONFIG += qt plugin

TARGET = $$qtLibraryTarget($$TARGET)
uri = ApplicationLauncher

# Input
SOURCES += \
    applicationlauncher_plugin.cpp \
    applicationlauncher.cpp \
    application.cpp

HEADERS += \
    applicationlauncher_plugin.h \
    applicationlauncher.h \
    application.h

OTHER_FILES = qmldir

!equals(_PRO_FILE_PWD_, $$OUT_PWD) {
    copy_qmldir.target = $$OUT_PWD/qmldir
    copy_qmldir.depends = $$_PRO_FILE_PWD_/qmldir
    copy_qmldir.commands = $(COPY_FILE) \"$$replace(copy_qmldir.depends, /, $$QMAKE_DIR_SEP)\" \"$$replace(copy_qmldir.target, /, $$QMAKE_DIR_SEP)\"
    QMAKE_EXTRA_TARGETS += copy_qmldir
    PRE_TARGETDEPS += $$copy_qmldir.target
}

qmldir.files = qmldir \
    applicationlauncher.qmltypes

linux-buildroot-g++ {
    installPath = /usr/qml/$$replace(uri, \\., /)
    qmldir.path = $$installPath
    target.path = $$installPath
    INSTALLS += target qmldir
} else {
    installPath = $$[QT_INSTALL_QML]/$$replace(uri, \\., /)
    qmldir.path = $$installPath
    target.path = $$installPath
    INSTALLS += target qmldir
}

DISTFILES += \
    applicationlauncher.qmltypes